Les Mongueurs de Perl / Groupe de travail Articles / Conférences Perl

Nous rejoindre / SVN / Relecture / Rédaction / Planning / Liens /

Publications : Linux Magazine France, Perles, Brèves, Production, Comptes-Rendus, Interviews, Traductions, Spoofathon

    $ perl -ne '18..21 and print' long_texte.txt

    #!/usr/bin/perl
    my($first,$last) = (shift,shift);
    $.==$first .. $.==$last and print while <>

    $ splice 185 202 long_texte.txt

    $ man perl | splice 319 322
    NOTES
        The Perl motto is "There's more than one way to do it."
        Divining how many more is left as an exercise to the
        reader.

    #!/usr/bin/perl
    sub usage { print STDERR "usage: splice LINES [file ...]\n" and exit -1 }
    my $lines = shift || usage();
    my(@first,@last,$i) = ();
    for my $block (split ',', $lines) {
        my @l = split '-', $block;
        push @first, $l[0];
        push @last, $l[1] || $first[-1];
    }
    ($.==$first[$i]||($.==$first[$i+1]&&++$i)) .. $.==$last[$i] and print while <>

L'exemple précédent s'écrit maintenant :

    $ man perl | splice 319-322
    NOTES
        The Perl motto is "There's more than one way to do it."
        Divining how many more is left as an exercise to the
        reader.

Plus intéressant, on peut maintenant indiquer plusieurs blocs de lignes à afficher. Pour illustrer cela, on crée d'abord un fichier qui ne contient que ses numéros de lignes :

    $ pseq 1 20 "line %d" >text

ou, pour ceux qui n'auraient pas conservé la Perle correspondante :

    $ perl -le 'print"line $_"for 1..20' >text

Exécutons maintenant splice en sélectionnant les lignes 8 à 9, 12 et 15 à 17.

    $ splice 8-9,12,15-17 text
    line 8
    line 9
    line 12
    line 15
    line 16
    line 17

Comme on le voit, seules les lignes indiquées sont affichées. Quant à ceux qui voudraient maintenant sélectionner des tranches non plus en fonction des numéros de lignes, mais en fonction du texte (en quelque sorte un mélange des fonctionnalités de splice et de grep(1)), il y a moyen de faire quelque chose, mais c'est plus délicat de trouver une manière générique de l'exprimer.

Par exemple l'uniligne suivant affiche le premier paragraphe de la section Author de perl(1) :

    $ man perl | col -b | perl -ne '/AUTHOR/../^$/ and print'
    AUTHOR
        Larry Wall <larry@wall.org>, with the help of oodles of
        other folks.

Comme précédemment, tout repose sur l'opérateur flip-flop, mais en lui passant cette fois en arguments des expressions régulières. Les plus observateurs auront remarqué la présence de col(1) dans le tube afin de supprimer le formatage écran de man(1).

En suivant la même route que pour splice, il est simple de transformer cet uniligne en petit script mgrep (comme multi-grep :

    #!/usr/bin/perl
    my($first,$last) = (shift,shift);
    /$first/../$last/ and print while <>

L'exemple précédent s'écrit alors :

    $ man perl | col -b | sgrep 'AUTHOR' '^$'
    AUTHOR
        Larry Wall <larry@wall.org>, with the help of oodles of
        other folks.

L'étape suivante, accepter plusieurs expressions régulières, est celle qu'il est plus difficile de rendre aussi élégante que pour splice. En effet, dans l'idéal nous voudrions pouvoir accepter n'importe quelle expression régulière, mais certains caractères sont nécessaires pour la syntaxe de délimitation de ces expressions à passer en argument à mgrep (en reprenant celle de splice, on utilise le tiret pour délimiter les expressions d'un couple et la virgule pour délimiter les couples). Ces caractères ne pourront donc pas être utilisés au sein des expressions régulières, à moins de vouloir coder un mécanisme d'échappement. Nous nous en tenons à la syntaxe de splice, en connaissant et acceptant ses limitations.

    #!/usr/bin/perl
    use strict;
    sub usage { print STDERR "usage: mgrep PATTERNS [file ...]\n" and exit -1 }
    my $patterns = shift || usage();
    my(@first,@last,$i) = ();
    for my $block (split ',', $patterns) {
        my @l = split '-', $block;
        push @first, $l[0];
        push @last, $l[1] || $first[-1];
    }
    (/$first[$i]/||(/$first[$i+1]/&&++$i)) .. /$last[$i]/ and print while <>

Un exemple d'exécution de mgrep ressemblera à ceci :

    $ man perl | col -b | mgrep AUTHOR-'^$',motto,virtues-why
    AUTHOR
        Larry Wall <larry@wall.org>, with the help of oodles of
        other folks.

        The Perl motto is "There's more than one way to do it."
        The three principal virtues of a programmer are Laziness,
        Impatience, and Hubris.  See the Camel Book for why.

Les arguments signifient : afficher la ligne qui contient « AUTHOR » et le paragraphe qui suit (paramètre AUTHOR-'^$'), afficher la ligne qui contient « motto » (paramètre motto), afficher le texte de la ligne qui contient « virtues » à la ligne qui contient « why » (paramètre virtues-why).

(Sébastien Aperghis-Tramoni (Maddingue), Marseille.pm - sebastien@aperghis.net)

Copyright © Les Mongueurs de Perl, 2001-2011 pour le site.
Les auteurs conservent le copyright de leurs articles.