Perles de Mongueurs (49)

Article publié dans Linux Magazine 127, mai 2010.

[+ del.icio.us] [+ Developers Zone] [+ Bookmarks.fr] [Digg this] [+ My Yahoo!]

La perle de ce mois-ci a été rédigée par Philippe "BooK" Bruhat (book@mongueurs.net), de Lyon.pm et Paris.pm.

Produire un PDF au format booklet

Je dispose d'un document PDF au format A5, que je veux imprimer sur des feuilles A4 puis agrafer pour faire un joli livret.

Certaines imprimantes sophistiquées permettent de le faire directement, mais ce n'est pas le cas de la mienne, ni probablement de celles des personnes qui vont essayer d'imprimer mon document. C'est pourquoi je préfère directement produire un document PDF au format A4, qu'il n'y aura plus qu'à imprimer en recto-verso.

L'ordre des pages est le suivant (en supposant un document avec un nombre de pages multiple de 4) :

    +-----+-----+    +-----+-----+
    |     |     |    |     |     |
    |  n  |  1  |    |  2  | n-1 |
    |     |     |    |     |     |
    +-----+-----+    +-----+-----+

    +-----+-----+    +-----+-----+
    |     |     |    |     |     |
    | n-2 |  3  |    |  4  | n-3 |
    |     |     |    |     |     |
    +-----+-----+    +-----+-----+

Autrement dit, pour tout groupe de quatre pages, 1, 2, 3, 4 devient 4, 1, 2, 3.

Donc, si on a la liste des pages dans un tableau @pages, les pages sont à traiter dans l'ordre suivant : dernière, première, première de ce qui reste, dernière de ce qui reste, et on répète tant qu'il y a des pages.

Soit en Perl :

    pop;
    shift;
    shift;
    pop;

Pour produire le nouveau PDF, le plus simple est de charger l'ancien PDF, et d'importer les pages dans le bon ordre en les traitant par groupe de quatre pour produire deux pages dans le nouveau document.

Si jamais le document à traiter n'a pas un nombre de pages suffisant, il suffit d'ajouter des pages bidons qui ne seront pas insérées.

Le module Perl de manipulation de PDF, PDF::API2 permet de faire tout cela.

    use strict;
    use warnings;
    use PDF::API2;

    # les fichiers
    my $oldfile = shift;
    (my $newfile = $oldfile) =~ s/\.pdf$/-booklet.pdf/;

    # charge l'ancien PDF
    my $old = PDF::API2->open($oldfile);

    # configure le nouveau PDF
    my $new = PDF::API2->new( -file => $newfile );
    $new->mediabox( 842, 595 );    # format A4 paysage

    # nombre de pages de l'ancien PDF
    my $pages = $old->pages;
    my @old   = 1 .. $old->pages;

    # ajoute le nombre de pages nécessaires
    # pour avoir un multiple de 4
    push @old, 0 for 1 .. ( 4 - $pages ) % 4;

    # ajoute les pages par groupe de 4
    while (@old) {
        my ( $n, $page );
        $page = $new->page;
        add_page( $new, $page, $old, pop @old,   0,   0 );
        add_page( $new, $page, $old, shift @old, 421, 0 );
        $page = $new->page;
        add_page( $new, $page, $old, shift @old, 0,   0 );
        add_page( $new, $page, $old, pop @old,   421, 0 );
    }

    # ajoute la page donnée du vieux document
    # dans la page fournie du nouveau à la position donnée
    sub add_page {
        my ( $new, $page, $old, $n, $x, $y ) = @_;
        return if !$n;    # ignore la page 0
        my $xo = $new->importPageIntoForm( $old, $n );
        my $gfx = $page->gfx;
        $gfx->formimage( $xo, $x, $y, 1 );
    }

    $new->save;

Les fonctions importantes dans ce code sont :

Dans le cas plus général (imprimer une documentation sous forme de livret pour économiser du papier), on veut en fait produire un livret A4 à partir d'un document en A4. La seule chose qui va changer, c'est l'échelle à laquelle on copie les pages. Le rapport est 0.707 (sqrt(2)/2). Ceci vient de la norme (ISO 216) définissant les dimensions du papier, qui est conçue de sorte que plier une feuille en deux conserve ses proportions. Le rapport des surfaces est de 1/2, et donc celui des longueurs de sqrt(2)/2.

Cependant, il est possible de devoir utiliser un ratio inférieur pour convertir un document en livret, en fonction des dimensions respectives des marges du documents et des marges d'impression de l'imprimante. En effet, les marges originales du document seront elles aussi réduites. Le cas échéant il faudra donc également repositionner les pages réduites pour que la marge d'impression ne morde pas sur le document.

Il a fallu 7 secondes à mon portable pour convertir un document de 3,8 mégaoctets et 572 pages, c'est-à-dire considérablement moins que le temps qu'il me faudra pour imprimer les 286 pages du document final. ;-)

Références

À vous !

Envoyez vos perles à perles@mongueurs.net, elles seront peut-être publiées dans un prochain numéro de Linux Magazine.

[IE7, par Dean Edwards] [Validation du HTML] [Validation du CSS]